Started code for DSP final project

2024-04-25 18:38:09 -04:00
parent 824a46b1fd
commit 50a5e57e18
96 changed files with 2160495 additions and 28 deletions
--- a/6th-Semester-Spring-2024/Power-Electronics/Simulations/BUCK.cir
+++ b/6th-Semester-Spring-2024/Power-Electronics/Simulations/BUCK.cir
@@ -0,0 +1,45 @@
+*--- SIMULATE FILE
+
+*---SIMULATION PARAMETERS
+.PARAM:
+ FS=100K 					;SYSTEM SWITCHING FREQUENCY
+ TS={1/FS}
+ W={2*PI*FS}
+ CYCLE=3					;SIMULATED CYCLES
+ START={500*TS}
+ END={START+CYCLE*TS}
+ STEP={TS/1000}
+
+.TRAN	{STEP}		{END}		{START}		{STEP}		UIC
+
+*---CIRCUIT PARAMETERS
+.PARAM:
+ VIN = 100
+ L1 = 50U
+ C1 = 20U
+ RL = 10
+ D = 0.5
+ TON = D*TS
+
+*--- DC POWER SUPPLY
+VIN		IN		0		{VIN}
+
+*--- CIRCUIT DISCRIPTION
+S1		IN		S1OUT	GP		0		MYSWITCH
+D1		0		S1OUT	MYDIODE
+
+L1		S1OUT	L1OUT	{L1}	IC=0
+C1		L1OUT	0		{C1}	IC=0
+
+*--- LOAD RESISTANCE
+RL		L1OUT	0		{RL}
+
+*--- CONTROL SIGNAL FOR THE SWITCH
+VGP		GP		0		PULSE(0		10		0		0.1U		0.1U		{TON-0.1U}		{TS})
+RGP		GP		0		100K
+
+*--- MEASURE POWER AND EFFICIENCY
+.MEAS	TRAN	VOUT	AVG		V(L1OUT)
+
+.MODEL MYDIODE D(RON=0.1M ROFF=100MEG VFWD=0.1M)
+.MODEL MYSWITCH SW(RON=0.1M ROFF=100MEG VT=3)